***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jun 26, 2017                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt PJC7428 drain gate source
rg     gate    1t    1
m1      2    1    3    3    dmos    l=1u   w=1u
.model dmos nmos ( vto = {0.798*((-1.5e-3*temp)+1)}	kp = {2.295*((4.8e-3*temp)+1)}
+theta = 0.1	tnom = 25	vmax = 2.2e5	level = 3)   
cgs	1t	3	50p	ic = 0
rd	drain	4	0.267	tc=0.005
dds	3	4	dds
.model dds d(bv = 31.35	ibv = 0.25e-6	tbv1 = 0.001  m=0.36  cjo=23p   vj=0.8)
e_e1         1 3 table { v(1t, 30) } 
+ ((0, 0) 
+  (2.5, 2.42) 
+  (3, 2.9)
+  (3.5, 3.5)
+  (4, 4)
+  (4.5, 4.5)
+  (5, 5)
+  (10, 8)
+  (11, 9) )
dbody   3   drain    dbody
.model   dbody    d(is=6e-8	n=1.95	rs={-0.4*(1-0.97*(temp-25))}	
+tt=100n	vj=0.8	eg = 0.96 )
ra      4    2    0.28  tc=0.0065
rs      3    5    10m
ls      5    source   0.0001n
m2      1t    8    6    6   inter
e2      8    6    4    1t   2
.model	inter	nmos(vto=0	kp=10	level=1) 
cgdmax  7    4    10p ic=0
rcgd    7    4    10meg
dgd     6    4    dgd
rdgd    4    6    10meg
.model     dgd    d(m=0.3   cjo=68p   vj=0.4)
m3      7    9    1t    1t   inter
e3      9    1t    4    1   -2
.ends
*$
